10 REM SECHS VERLIERT   =========64
20 REM (C)      COMMODORE WELT    =
30 REM ============================
40 REM (P)       REGINALD SCHOLZ  =
50 REM                            =
60 REM                            =
70 REM                            =
80 REM C-64 + 1530/1541           =
90 REM ============================
100 POKE53280,2:POKE53281,2
110 WH$=CHR$(5):C4$=CHR$(17)
120 RN$=CHR$(18):HE$=CHR$(19)
130 RE$=CHR$(28):C3$=CHR$(29)
140 GR$=CHR$(30):BL$=CHR$(31)
150 S1$=CHR$(32):BK$=CHR$(144)
160 C2$=CHR$(145):RF$=CHR$(146)
170 CL$=CHR$(147):PU$=CHR$(156)
180 C1$=CHR$(157):YE$=CHR$(158)
190 Z1$=CHR$(96):Z2$=CHR$(98)
200 ZC$=CHR$(183):ZD$=CHR$(113)
210 FORQ=1TO40:Q1$=Q1$+Z1$:NEXT
220 FORQ=1TO13:Q2$=Q2$+Z1$:NEXT
230 FORQ=1TO11:Q3$=Q3$+C3$:NEXT
240 FORQ=1TO29:S$=S$+S1$:NEXT
250 C$=HE$
260 FORQ=1TO23:C$=C$+C4$:NEXT
270 FORQ=1TO5:C$=C$+C3$:NEXT
280 FORQ=1TO10:TT$=TT$+S1$:NEXT
290 K$="NICHTS GEHT MEHR !    "+TT$+S1$
300 SS=0:CS=0
310 GOSUB1240
320 PRINTCL$BK$LEFT$(Q1$,39)
330 PRINTYE$" DAS SUPERWUERFELSPIEL"
340 PRINTBK$LEFT$(Q1$,39)
350 PRINTC4$WH$" KENNEN SIE DIE SPIELREGELN BEREITS ?"
360 PRINTC4$" (J/N)"
370 POKE198,0:WAIT198,1:GETA$
380 IFA$="N"THENGOSUB2030
390 GOSUB1060
400 PRINTC$;:INPUT" IHR NAME BITTE ";N$
410 IFLEN(N$)>8THENPRINTC2$C2$"MAXIMAL 8 BUCHSTABEN !    ":PRINTC$S$:GOTO400
420 GOSUB1060
430 T1=0:T2=0:Z1=0:Z2=0
440 FF=INT(RND(1)*2+1)
450 IFFF=1THEN600
460 PRINTC$S$
470 PRINTC$;"'TASTE'  =  WUERFELN          "
480 POKE198,0:WAIT198,1:GETA$
490 IFA$<>" "THEN480
500 GOSUB1750:GOSUB1450:GOSUB1830
510 IFW1=6ORW2=6THENPRINTC$S$C$K$:GOTO580
520 PRINTC$;"'TASTE' = WUERFELN  'H' = HALTEN"
530 POKE198,0:WAIT198,1:GETA$
540 IFA$=" "THEN500
550 IFA$<>"H"THEN530
560 PRINTC$S$C$N$;TAB(14);"HAELT "Z2" PUNKTE !      "
570 T2=T2+Z2:IFT2>99THEN730
580 Z2=0:GOSUB1610
590 FORI=1TO2000:NEXT
600 FF=1:PRINTC$S$
610 PRINTC$"COMPUTER WUERFELT !  "TT$
620 FORI=1TO1000:NEXT
630 GOSUB1750:GOSUB1450:GOSUB1830
640 IF W1=6ORW2=6THENPRINTC$S$C$K$:GOTO690
650 GOSUB1910
660 IF JN=1THEN610
670 PRINTC$S$C$;"COMPUTER HAELT"Z1"PUNKTE"TT$:FORI=1TO2000:NEXT
680 T1=T1+Z1
690 Z1=0:GOSUB1610
700 IF T1>99THEN800
710 FF=2
720 GOTO460
730 REM ***************************
740 REM *********** SPIELER SIEGT *
750 REM ***************************
760 PRINTC$S$C$C1$C1$C1$C1$C1$N$" HAT MIT"T2":"T1" GEWONNEN"
770 SS=SS+1
780 FORI=1TO3000:NEXT
790 GOTO900
800 REM ***************************
810 REM ********** COMPUTER SIEGT *
820 REM ***************************
830 PRINTC$S$C$C1$C1$C1$C1$C1$"COMPUTER HAT MIT"T1":"T2" GEWONNEN"
840 CS=CS+1
850 FORI=1TO3000:NEXT
860 REM ***************************
870 REM ************* GESAMTSTAND *
880 REM ***************************
890 GOSUB1060
900 PRINTLEFT$(C$,7);
910 PRINTTAB(13);RN$YE$" GESAMTSTAND "
920 PRINTTAB(13);RN$YE$Q2$
930 PRINTTAB(13);RN$YE$TT$LEFT$(S$,3)
940 PRINTTAB(13);RN$YE$C2$S1$N$;TAB(23);STR$(SS)
950 PRINTTAB(13);RN$YE$Q2$
960 PRINTTAB(13);RN$YE$TT$LEFT$(S$,3)
970 PRINTTAB(13);RN$YE$C2$" CBM-64"TAB(23);STR$(CS)
980 PRINTC$S$C$" "RN$"NOCHMAL ?"
990 POKE198,0:WAIT198,1:GETA$
1000 IFA$="J"THEN420
1010 IFA$<>"N"THEN990
1020 END
1030 REM ***************************
1040 REM ************** BILDAUFBAU *
1050 REM ***************************
1060 PRINTCL$:POKE53280,6:POKE53281,6
1070 PRINTC4$Q3$RN$WH$ZC$LEFT$(S$,16)ZC$
1080 PRINTLEFT$(Q3$,9)RN$ZC$"    SECHS VERLIERT  "ZC$
1090 PRINTLEFT$(Q3$,7)RN$ZC$LEFT$(S$,24)ZC$
1100 FORI=1TO9
1110 PRINTTAB(10);RN$Z2$RF$;TAB(29);RN$Z2$RF$
1120 NEXT
1130 PRINTLEFT$(Q3$,9)RN$LEFT$(S$,8)" WURF  TOTAL"LEFT$(S$,2)
1140 PRINTLEFT$(Q3$,8)RN$LEFT$(S$,24)
1150 PRINTLEFT$(Q3$,7)RN$S1$" CBM-64    0      0"LEFT$(S$,6)
1160 PRINTLEFT$(Q3$,5)RN$S$S1$
1170 PRINTLEFT$(Q3$,3)RN$LEFT$(S$,16)"0      0"LEFT$(S$,10)
1180 PRINTC3$RN$S$LEFT$(S$,9)
1190 PRINTC2$C2$RN$;TAB(15-LEN(N$));N$
1200 RETURN
1210 REM **************************
1220 REM ****** WUERFELDEFINITION *
1230 REM **************************
1240 DIM W$(6,5)
1250 W1$=RN$+WH$+S1$+S1$+ZD$+S1$+S1$
1260 W2$=RN$+WH$+ZD$+LEFT$(S$,4)
1270 W3$=RN$+WH$+ZD$+LEFT$(S$,3)+ZD$
1280 W4$=RN$+WH$+ZD$+S1$+ZD$+S1$+ZD$
1290 W5$=RN$+WH$+LEFT$(S$,4)+ZD$
1300 FORI=1TO6
1310 FORJ=1TO5
1320 W$(I,J)=RN$+WH$+LEFT$(S$,5)
1330 NEXTJ
1340 NEXTI
1350 W$(1,3)=W1$
1360 W$(2,1)=W2$:W$(2,5)=W5$
1370 W$(3,1)=W2$:W$(3,3)=W1$:W$(3,5)=W5$
1380 W$(4,1)=W3$:W$(4,5)=W3$
1390 W$(5,1)=W3$:W$(5,3)=W1$:W$(5,5)=W3$
1400 W$(6,1)=W4$:W$(6,5)=W4$
1410 RETURN
1420 REM **************************
1430 REM ******* WUERFEL ZEICHNEN *
1440 REM **************************
1450 PRINTLEFT$(C$,7);
1460 FORI=1TO5
1470 PRINTTAB(13)LEFT$(S$,14)
1480 NEXT
1490 PRINTLEFT$(C$,7)
1500 FORI=1TO5
1510 PRINTTAB(14)W$(W1,I)
1520 NEXT
1530 PRINTLEFT$(C$,7)
1540 FORI=1TO5
1550 PRINTTAB(21)W$(W2,I)
1560 NEXT
1570 RETURN
1580 REM **************************
1590 REM ************** PROTOKOLL *
1600 REM **************************
1610 IFFF=2THEN1670
1620 Z$=STR$(Z1):Z$=RIGHT$(Z$,LEN(Z$)-1)
1630 T$=STR$(T1):T$=RIGHT$(T$,LEN(T$)-1)
1640 PRINTLEFT$(C$,17)RN$TAB(16)LEFT$(S$,17)
1650 PRINTLEFT$(C$,17)RN$TAB(20-LEN(Z$));Z$;TAB(27-LEN(T$));T$
1660 GOTO1710
1670 Z$=STR$(Z2):Z$=RIGHT$(Z$,LEN(Z$)-1)
1680 T$=STR$(T2):T$=RIGHT$(T$,LEN(T$)-1)
1690 PRINTLEFT$(C$,19)RN$TAB(16)LEFT$(S$,17)
1700 PRINTLEFT$(C$,19)RN$TAB(20-LEN(Z$));Z$;TAB(27-LEN(T$));T$
1710 RETURN
1720 REM **************************
1730 REM *************** WUERFELN *
1740 REM **************************
1750 FORI=1TO20:PRINTLEFT$(C$,10)TAB(13)YE$"W U E R F E L N"WH$
1760 PRINTLEFT$(C$,10)TAB(13)LEFT$(S$,15):NEXT
1770 W1=INT(RND(1)*6+1)
1780 W2=INT(RND(1)*6+1)
1790 RETURN
1800 REM **************************
1810 REM ****** PROTOKOLL FUEHREN *
1820 REM **************************
1830 IF FF=1THEN1850
1840 Z2=Z2+W1+W2:GOTO1860
1850 Z1=Z1+W1+W2
1860 GOSUB1610
1870 RETURN
1880 REM **************************
1890 REM *********** COMPUTER-ZUG *
1900 REM **************************
1910 IFZ1>30 THENJN=2:GOTO1990
1920 JN=1
1930 IFRND(1)<.1THENJN=2:GOTO1990
1940 IFINT(RND(1)*(T1+T2))<6THENJN=1:GOTO1990
1950 IF T1+Z1>99THENJN=2
1960 IF Z1>13THENJN=2
1970 IFRND(1)<.4THEN1990
1980 IFZ1>7ANDT1-T2>10THENJN=2
1990 RETURN
2000 REM **************************
2010 REM ************* ERKLAERUNG *
2020 REM **************************
2030 PRINTCL$BK$LEFT$(Q1$,39)
2040 PRINTYE$" SPIELREGELN FUER DAS WUERFELSPIEL."
2050 PRINTBK$LEFT$(Q1$,39)
2060 PRINTC4$WH$" >> SECHS VERLIERT << WIRD MIT ZWEI"
2070 PRINTC4$" WUERFELN GESPIELT. SIE SPIELEN GEGEN"
2080 PRINTC4$" DEN COMPUTER UND DAS ZIEL IST ES, 100"
2090 PRINTC4$" ODER MEHR PUNKTE VOR DEM COMPUTER ZU"
2100 PRINTC4$" ERREICHEN. FUER EINEN GLUECKSRITTER "
2110 PRINTC4$" DUERFTE DAS KEIN PROBLEM SEIN."
2120 PRINTC4$" SPIELEN SIE VORSICHTIG, DER COMPUTER"
2130 PRINTC4$" HAT EINIGE TRICKS DRAUF."
2140 PRINTC4$" "RN$"           WEITER MIT SPACE           "
2150 POKE198,0:WAIT198,1:GETA$
2160 IFA$<>" "THEN2150
2170 PRINTCL$BK$LEFT$(Q1$,39)
2180 PRINTYE$" SPIELREGELN FUER DAS WUERFELSPIEL"
2190 PRINTBK$LEFT$(Q1$,39)
2200 PRINTC4$WH$" WENN SIE AM ZUG SIND, KOENNEN SIE SO"
2210 PRINTC4$" OFT WUERFELN WIE SIE WOLLEN. DABEI"
2220 PRINTC4$" WIRD, WENN SIE DIE PUNKTZAHL HALTEN"
2230 PRINTC4$" WOLLEN, DIESE PUNKTZAHL IHREM TOTAL-"
2240 PRINTC4$" STAND ZUGEZAEHLT. SOLLTEN SIE ALLER-"
2250 PRINTC4$" DINGS EINE 6 WUERFELN, SO VERFAELLT"
2260 PRINTC4$" DIE GESAMTE PUNKTZAHL UND DER C-64"
2270 PRINTC4$" IST MIT SEINEN VERSUCHEN DRAN."
2280 PRINTC4$" "RN$"           WEITER MIT SPACE           "
2290 POKE198,0:WAIT198,1:GETA$
2300 IFA$<>" "THEN2290
2310 RETURN
2320 REM SECHS VERLIERT   =======64
2330 REM 38911 BYTES MEMORY    ====
2340 REM 06397 BYTES PROGRAM   ====
2350 REM 00308 BYTES VARIABLES ====
2360 REM 00135 BYTES ARRAYS    ====
2370 REM 02717 BYTES STRINGS   ====
2380 REM 30356 BYTES FREE      ====